# Construction du Dispositif : Arduino et Raspberry Pi

## Matériel nécessaire :

1xArduino Uno   
1x Électrode + adaptateur pour électrode  
1x Résistance (1MΩ)  
2x Résistance (220 Ω)  
1x Potentiomètre (10 kΩ)  
1x LED  
1x Connecteur MIDI 5 Pin  
1x Câble MIDI vers USB  
Câbles de connexion pour Arduino (jumper wires)  
1x Platine d’essai  
1x Platine pour souder pour Arduino UNO  
Fil à souder  
1x Câble USB pour Arduino  
1x Boîtier adapté pour Arduino

-Raspberry Pi 4

-Carte son HifiBerry

-Carte microSD

-Câble 2 RCA mâle vers mini jack 3.5mm

-Enceinte et câble audio mini jack 3.5mm

-Répartiteur audio

-Écouteurs  
-Boîtier adapté pour Raspberry avec HifiBerry

2xBatteries portables

1x Ordinateur avec Arduino IDE et RNBO installés

## Instructions :

##### - Schéma de câblage pour le circuit avec Arduino

1. **Capteur Capacitif**
   * Connectez une broche de la résistance de 1 MΩ à la broche **4** de l'Arduino.
   * Connectez l'autre broche de la résistance à la broche **2** de l'Arduino.
   * Connectez la broche **2** de l'Arduino à une électrode (le capteur capacitif) avec son adaptateur.
2. **LED**
   * Connectez la broche longue (anode) de la LED à la broche **13** de l'Arduino.
   * Connectez la broche courte (cathode) de la LED à la masse (GND) de l'Arduino via une résistance de **220 Ω**.
3. **Potentiomètre**
   * Connectez une broche extérieure du potentiomètre à **5V**.
   * Connectez l'autre broche extérieure à **GND**.
   * Connectez la broche centrale du potentiomètre à la broche analogique **A0** de l'Arduino.
4. **Connecteur MIDI**
   * Connectez la broche **5** du connecteur MIDI à la broche **TX** de l'Arduino.
   * Connectez la broche **4** du connecteur MIDI à **5V** via une résistance de **220 Ω**.
   * Connectez la broche **2** du connecteur MIDI à la masse (GND).

### -Code Arduino

Branchez l’Arduino à l’ordinateur par USB et ajoutez le code suivant au dispositif via le logiciel Arduino IDE :

#include <CapacitiveSensor.h>

CapacitiveSensor cs\_4\_2 = CapacitiveSensor(4, 2);

long baselineReading = 0;

const int midiNoteLow = 21;

const int midiNoteHigh = 127;

long minExpectedReading = 0;

long maxExpectedReading = 17000;

int threshold = 50;

const int debounceTime = 100;

const int ledPin = 13;

const int potPin = A0;

static long lastReading = 0;

static int lastNote = -1;

unsigned long lastNoteTime = 0;

unsigned long lastNoteOnTime = 0;

const unsigned long noteOffTimeout = 2000;

void setup() {

cs\_4\_2.set\_CS\_AutocaL\_Millis(0xFFFFFFFF);

Serial.begin(31250);

pinMode(ledPin, OUTPUT);

pinMode(potPin, INPUT);

baselineReading = cs\_4\_2.capacitiveSensor(1000);

}

void loop() {

long total = cs\_4\_2.capacitiveSensor(1000);

long normalizedReading = total - baselineReading;

unsigned long currentTime = millis();

int potValue = analogRead(potPin);

threshold = map(potValue, 0, 1023, 5, 500);

if (normalizedReading < minExpectedReading) minExpectedReading = normalizedReading;

if (normalizedReading > maxExpectedReading) maxExpectedReading = normalizedReading;

bool isNoteActive = abs(normalizedReading - lastReading) > threshold;

if (isNoteActive && (currentTime - lastNoteTime) > debounceTime) {

normalizedReading = constrain(normalizedReading, minExpectedReading, maxExpectedReading);

int mappedNote = map(normalizedReading, minExpectedReading, maxExpectedReading, midiNoteLow, midiNoteHigh);

mappedNote = constrain(mappedNote, midiNoteLow, midiNoteHigh);

mappedNote = mapToCMajor(mappedNote);

if (mappedNote != lastNote) {

if (lastNote != -1) midiNoteOff(lastNote, 127);

midiNoteOn(mappedNote, 127);

lastNote = mappedNote;

lastNoteOnTime = currentTime;

}

lastReading = normalizedReading;

lastNoteTime = currentTime;

} else if (!isNoteActive && lastNote != -1 && (currentTime - lastNoteOnTime) > debounceTime) {

midiNoteOff(lastNote, 127);

lastNote = -1;

lastNoteOnTime = 0;

}

}

void midiNoteOn(int note, int velocity) {

digitalWrite(ledPin, HIGH);

delay(10);

digitalWrite(ledPin, LOW);

Serial.write(0x90);

Serial.write(note);

Serial.write(velocity);

}

void midiNoteOff(int note, int velocity) {

digitalWrite(ledPin, LOW);

Serial.write(0x80);

Serial.write(note);

Serial.write(0);

}

int mapToCMajor(int note) {

int noteInScale;

int noteDistance = note % 12;

if (noteDistance <= 1) noteInScale = 0;

else if (noteDistance <= 3) noteInScale = 2;

else if (noteDistance <= 5) noteInScale = 4;

else if (noteDistance <= 6) noteInScale = 5;

else if (noteDistance <= 8) noteInScale = 7;

else if (noteDistance <= 10) noteInScale = 9;

else noteInScale = 11;

return (note / 12) \* 12 + noteInScale;

}

- Configuration du Raspberry Pi avec RNBO

#### **Préparation de la carte microSD**

1. Téléchargez l'image prête à l'emploi de RNBO pour Raspberry Pi depuis le site [Cycling '74](https://rnbo.cycling74.com/learn/raspberry-pi-target-overview)
2. Utilisez le logiciel *Raspberry Pi* Imager pour flasher l'image sur la carte microSD.
3. Configurez le réseau WiFi, le nom d'hôte, et activez SSH + Configure Wireless Lan lors du flashage.

#### **Installation de la carte son HifiBerry**

1. Connectez la carte son HifiBerry aux broches GPIO du Raspberry Pi.
2. Connectez le câble RCA aux sorties de la carte son HifiBerry.
3. Branchez l'autre extrémité du câble RCA au répartiteur audio via le mini jack 3.5mm.
4. Branchez les enceintes et les écouteurs au répartiteur audio.

#### - Mise en place du Raspberry Pi avec l’Arduino

1. Insérez la carte microSD dans le Raspberry Pi.
2. Branchez le câble MIDI->USB entre le connecteur femelle 5 PIN de l'Arduino et une des entrées USB du Raspberry Pi.
3. Allumez le Raspberry Pi en le connectant à la batterie portable.
4. Depuis le logiciel Max, exportez votre patch RNBO vers le Raspberry Pi via le réseau partagé. Le Raspberry Pi devrait apparaître sous la section *Devices* de la barre latérale *Export*.
5. Placez l'électrode sur une feuille de la plante.
6. Allumez l'Arduino en le connectant à la batterie portable.
7. Testez le dispositif en touchant la plante. Utilisez le potentiomètre pour régler le seuil de variabilité de la conductivité.